,,

[點晴永久免費OA]日期函數擴展類Ver0.1.1

admin

2022年7月4日 21:36 本文熱度 1326

代碼如下：
<%
Class DateFunEx

 Private d_
 Private firstweekofyear_
 Private firstdayofweek_

 Private Sub class_initialize()
 d_ = date() '默認當前日期
 firstdayofweek_ = 2 'vbMonday
 firstweekofyear_ = 1 '由 1 月 1 日所在的星期開始。
 End Sub

 '屬性 setDate 日期
 Public Property Let setDate(value)
 On Error Resume Next
 If IsNumeric(value) Then
 value = Cint(value)
 If len(value)< 3 Then value = "20" & right("0"&value,2)
 value = value & "-1"
 End If
 d_ = cDate(value)
 End Property

 '屬性 firstweekofyear 每年的第一周(詳細設置請參照VBS手冊)
 Public Property Let firstweekofyear(value)
 firstweekofyear_ = cInt(value)
 End Property

 '屬性 FirstDayofWeek 每周的第一天(詳細設置請參照VBS手冊)
 Public Property Let firstdayofweek(value)
 firstdayofweek_ = cInt(value)
 End Property

 '------------------------------
 ' 功能說明:算第幾周的星期幾是幾號
 ' 參數說明:y 年,w周,week 星期 (星期一1 星期天7)
 '------------------------------
 Public Function GetWeekDate(y, w, DayofWeek)
 Dim NewYearDay
 NewYearDay = CDate(y & "-1-1") '元旦
 GetWeekDate = ((NewYearDay - Weekday(NewYearDay, firstdayofweek_)) + (w - 1) * 7 + DayofWeek)
 End Function

 '------------------------------
 ' 功能說明:獲得某年某月的天數
 '------------------------------
 Public Function GetMonthDayCount()
 GetMonthDayCount = DateDiff("d", d_, DateAdd("m", 1, d_))
 End Function

 '------------------------------
 ' 功能說明:得到某年某月的第一天
 '------------------------------
 Public Function GetMonthFirstDay()
 GetMonthFirstDay = CDate( Year(d_) & "-" & Month(d_) & "-1")
 End Function

 '------------------------------
 ' 功能說明:得到某年的某月的最后一天
 '------------------------------
 Public Function GetMonthLastDay()
 GetMonthLastDay = CDate( Year(d_) & "-"&Month(d_) & "-" & DateDiff("d", d_, DateAdd("m", 1, d_)))
 End Function

 '------------------------------
 ' 功能說明:某日所在的周的第一天的日期
 '------------------------------
 Public Function WeekFirstDay()
 WeekFirstDay = GetWeekDate(Year(d_), DatePart("ww", d_,firstdayofweek_,firstweekofyear_), 1)
 End Function

 '------------------------------
 ' 功能說明:某日所在的周的第最后一天的日期
 '------------------------------
 Public Function WeekLastDay()
 WeekLastDay = GetWeekDate(Year(d_), DatePart("ww", d_,firstdayofweek_,firstweekofyear_), 7)
 End Function

End Class
%>

測試頁面代碼如下：
<%@LANGUAGE="VBscript" CODEPAGE="936"%>
<% Option Explicit %>
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
<head>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312" />
<title>Test_clsDateFunEx</title>
</head>
<body>

<%
Dim myDateFun,strDate
strDate = "2005-4-1"
Set myDateFun = new DateFunEx
 myDateFun.setDate = strDate
 Response.write "2006年第2周的星期一是幾號:" & _
 myDateFun.GetWeekDate(2006,2,1) &" "
 Response.Write "2005年4月的天數:"&_
 myDateFun.GetMonthDayCount & " "
 Response.Write "2005年4月的第一天:"&_
 myDateFun.GetMonthFirstDay & " "
 Response.Write "2005年4月的最后一天:"&_
 myDateFun.GetMonthLastDay & " "
 Response.Write "2005年4月1日所在的周的第一天的日期:"&_
 myDateFun.WeekFirstDay & " "
 Response.Write "2005年4月1日所在的周的第最后一天的日期:" & _
 myDateFun.WeekLastDay & " "
Set myDateFun = Nothing
%>
</body>
</html>

該文章在 2022/7/4 21:36:24 編輯過

關鍵字查詢

1.1

函數

日期

正在查詢...

點晴ERP是一款針對中小制造業(yè)的專業(yè)生產管理軟件系統,系統成熟度和易用性得到了國內大量中小企業(yè)的青睞。

點晴PMS碼頭管理系統主要針對港口碼頭集裝箱與散貨日常運作、調度、堆場、車隊、財務費用、相關報表等業(yè)務管理，結合碼頭的業(yè)務特點，圍繞調度、堆場作業(yè)而開發(fā)的。集技術的先進性、管理的有效性于一體，是物流碼頭及其他港口類企業(yè)的高效ERP管理信息系統。

點晴WMS倉儲管理系統提供了貨物產品管理,銷售管理,采購管理,倉儲管理,倉庫管理,保質期管理,貨位管理,庫位管理,生產管理,WMS管理系統,標簽打印,條形碼,二維碼管理,批號管理軟件。

點晴免費OA是一款軟件和通用服務都免費，不限功能、不限時間、不限用戶的免費OA協同辦公管理系統。

日本xxxx18视频在线观看-日本xxxx1819-日本xxxwww在线观看-日本xxx-日本xx-日本www在线视频

[點晴永久免費OA]日期函數擴展類Ver0.1.1